From de6b12502cdf42d5d92118f1c0e38dc31becf7c5 Mon Sep 17 00:00:00 2001
From: Rene Mayrhofer <rene@mayrhofer.eu.org>
Date: Tue, 23 Feb 2010 10:42:46 +0000
Subject: Updated to new upstream release. interfaces Patch is not from
 upstream.

---
 m4/macros/enable-disable.m4 | 32 ++++++++++++++++++++++++++++++++
 m4/macros/with.m4           | 24 ++++++++++++++++++++++++
 2 files changed, 56 insertions(+)
 create mode 100644 m4/macros/enable-disable.m4
 create mode 100644 m4/macros/with.m4

(limited to 'm4/macros')

diff --git a/m4/macros/enable-disable.m4 b/m4/macros/enable-disable.m4
new file mode 100644
index 000000000..6d7959e4e
--- /dev/null
+++ b/m4/macros/enable-disable.m4
@@ -0,0 +1,32 @@
+
+# ARG_ENABL_SET(option, help)
+# ---------------------------
+# Create a --enable-$1 option with helptext, set a variable $1 to true/false
+AC_DEFUN([ARG_ENABL_SET],
+	[AC_ARG_ENABLE(
+		[$1],
+		AS_HELP_STRING([--enable-$1], [$2]),
+		[if test x$enableval = xyes; then
+			patsubst([$1], [-], [_])=true
+		 else
+			patsubst([$1], [-], [_])=false
+		fi],
+		patsubst([$1], [-], [_])=false
+	)]
+)
+
+# ARG_DISBL_SET(option, help)
+# ---------------------------
+# Create a --disable-$1 option with helptext, set a variable $1 to true/false
+AC_DEFUN([ARG_DISBL_SET],
+	[AC_ARG_ENABLE(
+		[$1],
+		AS_HELP_STRING([--disable-$1], [$2]),
+		[if test x$enableval = xyes; then
+			patsubst([$1], [-], [_])=true
+		 else
+			patsubst([$1], [-], [_])=false
+		fi],
+		patsubst([$1], [-], [_])=true
+	)]
+)
diff --git a/m4/macros/with.m4 b/m4/macros/with.m4
new file mode 100644
index 000000000..908333b47
--- /dev/null
+++ b/m4/macros/with.m4
@@ -0,0 +1,24 @@
+
+# ARG_WITH_SUBST(option, default, help)
+# -----------------------------------
+# Create a --with-$1 option with helptext, AC_SUBST($1) to $withval/default
+AC_DEFUN([ARG_WITH_SUBST],
+	[AC_ARG_WITH(
+		[$1],
+		AS_HELP_STRING([--with-$1=arg], [$3 (default: $2).]),
+		[AC_SUBST(patsubst([$1], [-], [_]), ["$withval"])],
+		[AC_SUBST(patsubst([$1], [-], [_]), ["$2"])]
+	)]
+)
+
+# ARG_WITH_SET(option, default, help)
+# -----------------------------------
+# Create a --with-$1 option with helptext, set a variable $1 to $withval/default
+AC_DEFUN([ARG_WITH_SET],
+	[AC_ARG_WITH(
+		[$1],
+		AS_HELP_STRING([--with-$1=arg], [$3 (default: $2).]),
+		patsubst([$1], [-], [_])="$withval",
+		patsubst([$1], [-], [_])=$2
+	)]
+)
-- 
cgit v1.2.3